Lorenz96_slow_fast_empire.f90

Go to the documentation of this file.

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!    Implements Lorenz 1996 model with slow/fast modes as in
!    Bergemann 2010 http://doi.wiley.com/10.1002/qj.672
!
!The MIT License (MIT)
!
!Copyright (c) 2015 Philip A. Browne
!
!Permission is hereby granted, free of charge, to any person obtaining a copy
!of this software and associated documentation files (the "Software"), to deal
!in the Software without restriction, including without limitation the rights
!to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
!copies of the Software, and to permit persons to whom the Software is
!furnished to do so, subject to the following conditions:
!
!The above copyright notice and this permission notice shall be included in all
!copies or substantial portions of the Software.
!
!THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
!IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
!FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
!AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
!LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
!OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
!SOFTWARE.
!
!Email: p.browne@reading.ac.uk
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

program lorenz96_slow_fast
  implicit none
  include 'mpif.h'
  real(kind=kind(1.0D0)) :: dt=2.5d-3
  real(kind=kind(1.0D0)), allocatable, dimension(:,:) :: x,k1,k2,k3,k4
  real(kind=kind(1.0d0)) :: F=8.0d0
  real(kind=kind(1.0d0)) :: alpha=0.5d0
  real(kind=kind(1.0d0)) :: delta=0.5d0
  real(kind=kind(1.0d0)) :: epsilon=2.5d-3
  real(kind=kind(1.0d0)) :: gamma=0.1d0
  integer :: N=40
  integer :: total_timesteps=1000
  integer :: t
  integer :: mpi_err,mdl_id,cpl_root,cpl_mpi_comm
  integer, dimension(MPI_STATUS_SIZE) :: mpi_status
  integer :: ios
  logical :: l96_exists
  
  namelist/l96/n,&
       &total_timesteps,&
       &f,&
       &dt,&
       &delta,&
       &epsilon,&
       &alpha,&
       &gamma

  inquire(file='l96.nml', exist=l96_exists)
  if(l96_exists) then
     open(32,file='l96.nml',iostat=ios,action='read'&
          &,status='old')
     if(ios .ne. 0) stop 'Cannot open l96.nml'
     read(32,nml=l96) 
     close(32)
  end if




  call initialise_mpi(mdl_id,cpl_root,cpl_mpi_comm)


  allocate(x(n,3),k1(n,3),k2(n,3),k3(n,3),k4(n,3))
  x = f
  x(:,1) = f
  x(:,2) = f
  x(:,3) = 0.
  x(n/2,1) = f+0.05d0
  print*,x(:,1:2)

  if(mdl_id .eq. 0) then
     call mpi_send(x(:,1:2),n*2,mpi_double_precision,cpl_root&
          &,1,cpl_mpi_comm,mpi_err)
     call mpi_recv(x(:,1:2),n*2,mpi_double_precision,cpl_root&
          &,mpi_any_tag,cpl_mpi_comm,mpi_status,mpi_err)
  end if
2 continue


  do t = 1,total_timesteps
     k1 = g(x                  , n , f ,alpha,delta,epsilon,gamma)
     k2 = g(x +0.5d0 * dt * k1 , n , f ,alpha,delta,epsilon,gamma)
     k3 = g(x +0.5d0 * dt * k2 , n , f ,alpha,delta,epsilon,gamma)
     k4 = g(x +        dt * k3 , n , f ,alpha,delta,epsilon,gamma)
     x = x + dt *( k1 + 2.0d0 *( k2 + k3 ) + k4 )/6.0d0

     if(mdl_id .eq. 0) then
        call mpi_send(x(:,1:2),n*2,mpi_double_precision,cpl_root&
             &,1,cpl_mpi_comm,mpi_err)
        call mpi_recv(x(:,1:2),n*2,mpi_double_precision,cpl_root&
             &,mpi_any_tag,cpl_mpi_comm,mpi_status,mpi_err)
     end if
     print*,x(:,1:2)

     select case(mpi_status(mpi_tag))
     case(2)
        go to 2
     case(3)
        go to 3
     case default
     end select

  end do
3 continue
  call mpi_finalize(mpi_err)

contains
  function g (X , N, F ,alpha,delta,epsilon,gamma)
    implicit none
    real(kind=kind(1.0D0)),intent(in),dimension(N,3) :: X
    integer, intent(in) :: N
    real(kind=kind(1.0D0)),dimension(N,3) :: g
    real(kind=kind(1.0D0)),intent(in) :: F
    real(kind=kind(1.0D0)),intent(in) :: alpha
    real(kind=kind(1.0D0)),intent(in) :: delta
    real(kind=kind(1.0D0)),intent(in) :: epsilon
    real(kind=kind(1.0D0)),intent(in) :: gamma
    integer :: j

    g(1,1) = (1.0d0-delta)*(x(2,1)-x(n-1,1) )*x(n,1) + delta*(x(n,1)*x(2,2)-x(n-1,1)*x(n,2)) - x(1,1) + f
    g(1,2) = x(1,3)
    g(1,3) = (-x(1,2) + alpha**2*(x(2,2)-2*x(1,2)+x(n,2)) + x(1,1) - gamma*epsilon**2*x(1,3))/(epsilon**2)
    
    g(2,1) = (1.0d0-delta)*(x(3,1)-x(n,1) )*x(1,1) + delta*(x(1,1)*x(3,2)-x(n,1)*x(1,2)) - x(2,1) + f
    g(2,2) = x(2,3)
    g(2,3) = (-x(2,2) + alpha**2*(x(3,2)-2*x(2,2)+x(1,2)) + x(2,1) - gamma*epsilon**2*x(2,3))/(epsilon**2)
    

    do j = 3,n-1
       g(j,1) = (1.0d0-delta)*(x(j+1,1)-x(j-2,1))*x(j-1,1) + delta*(x(j-1,1)*x(j+1,2)-x(j-2,1)*x(j-1,2)) - x(j,1) + f
       g(j,2) = x(j,3)
       g(j,3) = (-x(j,2) + alpha**2*(x(j+1,2)-2*x(j,2)+x(j-1,2)) + x(j,1) - gamma*epsilon**2*x(j,3))/(epsilon**2)
    end do

    g(n,1) = (1.0d0-delta)*(x(1,1)-x(n-2,1) )*x(n-1,1) + delta*(x(n-1,1)*x(1,2)-x(n-2,1)*x(n-1,2)) - x(n,1) + f
    g(n,2) = x(n,3)
    g(n,3) = (-x(n,2) + alpha**2*(x(1,2)-2*x(n,2)+x(n-1,2)) + x(n,1) - gamma*epsilon**2*x(n,3))/(epsilon**2)



  end function g
  subroutine initialise_mpi(mdl_id,cpl_root,cpl_mpi_comm)
    implicit none
    include 'mpif.h'
    integer, intent(out) :: mdl_id,cpl_root,cpl_mpi_comm
    integer :: mdl_num_proc=1
    integer :: mpi_err,world_size,world_id
    integer :: cpl_colour
    integer :: particle_id,nens, da, nda
    integer :: mdl_mpi_comm,mdlcolour
    integer :: tmp_mdls_comm,models_id,models_size
    call mpi_init(mpi_err)
    da = 0
    call mpi_comm_rank(mpi_comm_world,world_id,mpi_err)
    call mpi_comm_size(mpi_comm_world,world_size,mpi_err)
    call mpi_comm_split(mpi_comm_world,da,world_id,tmp_mdls_comm,mpi_err)
    call mpi_comm_size(tmp_mdls_comm,models_size,mpi_err)
    call mpi_comm_rank(tmp_mdls_comm,models_id,  mpi_err)
    mdlcolour = models_id/mdl_num_proc
    call mpi_comm_split(tmp_mdls_comm,mdlcolour,models_id,mdl_mpi_comm,mpi_err)
    call mpi_comm_rank(mdl_mpi_comm,mdl_id,mpi_err)
    if(mdl_id .eq. 0) then
       cpl_colour = 9999
    else
       cpl_colour = mpi_undefined
    end if
    call mpi_comm_split(mpi_comm_world,cpl_colour,mdlcolour,cpl_mpi_comm,mpi_err)
    if(mdl_id .eq. 0) then
       call mpi_comm_size(cpl_mpi_comm,nens,mpi_err)
       call mpi_comm_rank(cpl_mpi_comm,particle_id,mpi_err)
       nda = world_size-models_size;nens = nens - nda
       cpl_root = ((nda*particle_id)/nens)+nens
    else
       cpl_root = -1
    end if
  end subroutine initialise_mpi
end program lorenz96_slow_fast